c64scene.pl

Kod: Zaznacz cały

IRQ_ENTER:
 		pha
		txa
		pha
		tya
		pha
		sec
base:	lda #$32
		sbc $dc04
		sta *+4
		bpl *
		lda #$a9
		lda #$a9
		lda #$a9
		lda $ea
//--------------------------------------------------
//Stable		 
.var IrqCounter = *+1
		ldx #$09	
		cpx #4	//badline row
		bne !+
		jsr _rts	//12 cycles waste
		jsr _rts	 
		cmp ($00,x)	 
		cmp $00	 
!:		lda #$10
		eor $d018
		sta $d018 	//shift sprite shapes (and colormap)
		lda #0
		sta $d030

.const d = 7		//difference between line with sprites
		ldy #$32-d
		dex
		bpl !+
		//jsr music_play
		ldy #$32	//line without sprites
		ldx #9
!:		stx IrqCounter
		sty base+1		
		lda D012_tab,x
		sta $d012
		ldy spointers_tab,x
		tya
		and #8
		bne !+
		
.for(var i=0;i<7;i++) {
		sty p_ColorMap+$03f8+i
		iny
		}
		bne !next+
!:
.for(var i=0;i<7;i++) {
		sty p_ColorMap2+$03f8+i
		iny
		}
!next:						
		lda Row_Y_tab,x
.for(var i=0;i<7;i++)		
		sta $d001+i*2
		 
IRQ_EXIT:	inc $d019
		pla
		tay
		pla
		tax
		pla
_RTI:	rti	
//--------------------------------------------------

D012_tab:
	.by $31+9*21, $31+8*21, $31+7*21, $31+6*21
	.by $30+5*21, $31+4*21, $31+3*21
	.by  $30+2*21, $31+1*21, $31
Row_Y_tab:
	.fill 10,[9-i]*21+$32
spointers_tab:
	.fill 10,[9-i]*8+$20